Description Robert Walter 2013-07-30 09:24:20 EDT

Created attachment 233937 [details]
grammar, test file, and stack dump

I boiled down my grammar to the possible minimum to illustrate what I believe is a re-producable deadlock. Here's the grammar you can use in a default Xtext project (also attached). Note that I tried this with the latest release (2.4.2) as well as the bleeding edge version of Xtext (2.4.3.v201307291041):

#############################################################
grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.common.Terminals

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

Script:
	charactersDefinition=CharactersDefinition?
	scenes+=Scene*;

CharactersDefinition:
	'characters' ':' characters+=CharacterDefinition (',' characters+=CharacterDefinition)*;

CharacterDefinition:
	name=ID;

Scene:
	'scene' description=STRING
	dialog=Dialog
	'end' 'scene';

Dialog://{Dialog} 
	defaults=Defaults
	hubs+=Hub*;

Defaults: {Defaults}
	dialogLines+=DialogLine*;

Hub:
	'hub' name=StringID
		choiceDialogs+=ChoiceDialog*
	'end';

StringID:
	STRING;

ChoiceDialog:
	modifiers=Modifiers 'choice' name=StringID? 
		dialogLines+=DialogLine*
	'end';

Modifiers:{Modifiers}
	single?='single'?  random?='random'?
;

DialogLine:
	character=[CharacterDefinition] ':' lines=STRING;
#############################################################

The grammar shows no warnings.
Write a program using this language, which looks like this:

#############################################################
characters: Foo, Bar

scene "Test"
 
	hub "Foo"
		choice "Foo"
	   		Foo: "foooo"
	  	end 
	  	
	  	// here you need to proceed to reproduce the deadlock...
	end

end scene
#############################################################
Save the above state once and then, manually(!), type the following at the marked position: 

	choice "" 

and, when the cursor is just inside the quotation marks, invoke the content assist feature (CTRL+SPACE).

This should lead to a re-producable deadlock. I attached the corresponding stack dump. The deadlock seems to appear when the main thread tries to acquire a read lock.


I found two possible changes I can do to my grammar so that the deadlock does not appear.

1. Add the {Dialog} Action to the dialog rule (maybe the Xtext grammar should display another warning here that the action is missing since the "Defaults" rule might be empty?)

2. Change the "Modifiers" rule to an unordered group, which, however, led to other problems I cannot recall right now:

Modifiers://{Modifiers}
	single?='single'? & random?='random'?
;